Feuerball

[schneida]

aber welches Objekt nehme ich dafür, oder wo finde ich es? Bis jetzt hab ich im CS noch keinen Feuerball gefunden, und nen neues Objekt mit dem Mesh von nem Feuerball funzt nicht, wird nicht angezeigt.

...

klar das das mesh eines Feuerballs nicht funts! ich such dir schnell den Script für das Objekt raus! edite den post entsprechend!

PHP-Code:

scn DEIN SCRIPTNAME

; come within range and this thing will shoot a fireball at you (range is 1200)

float timer
short ready
short inRange
short disabled
ref mySelf
ref myParent
short next
short SpellRank

begin onActivate

    if isActionRef player == 0
        if disabled == 0
            set disabled to 1
            set timer to 0
        else
            set disabled to 0
        endif
    endif

end

begin gameMode

    if disabled == 0
        
        if getDistance player < 1200  && timer <= 0
            if getDistance player > 600
                set inRange to 1
            endif
        endif

        if  timer <= 0 && inRange == 1
                playgroup forward 0
                set ready to 1
                set timer to 6
                set inRange to 0
            endif

        ;This section will choose the trap spell based on the PC's level... hopefully
        if player.GetLevel <= 7
            set SpellRank to 1
        elseif ( player.GetLevel >= 8 ) && ( player.GetLevel <= 15 )
            set SpellRank to 2
        elseif ( player.GetLevel >= 16 ) && ( player.GetLevel <= 20 )
            set SpellRank to 3
        elseif ( player.GetLevel >= 21 )
            set SpellRank to 4
        endif

        ; daisy-chain
        if next == 1 && timer <= 5
            set mySelf to getSelf
            set myParent to getParentRef
            myParent.activate mySelf 1
            set next to 0
        endif

        if timer <= 4 && ready == 1 
            ; check to make sure player is still in range
            if getDistance player < 1200 && getDistance player > 400
                ;Debug message
                ;message "Rank %.0f Fireball", SpellRank, 10
                if SpellRank == 1
                    cast StandardFireDamageTarget1Novice player
                elseif SpellRank == 2
                    cast StandardFireDamageTarget2Apprentice player
                elseif SpellRank == 3
                    cast StandardFireDamageArea3Journeyman player
                elseif SpellRank == 4
                    cast StandardFireDamageArea4Expert player
                endif
            endif
    
            set ready to 0
        endif

        if timer > 0
            set timer to timer - getSecondsPassed
        endif
    endif
end 

so ungefähr müsste das aussehn! das legst du auf ein kleines oder Unsichtbares Static, und das ganze müsste funktionieren, den abstand kannst du noch ändern!