Zitat
begin Pub_Meine_Taverne
;Cell: Balmora, Meine Taverne
;Publican: Meine_Taverne_Wirt
;Flag: Rent_Meine_Taverne
;all rooms get rented for one day
;This guy must be in the map where the room is if you use the locked door cell loading cleanup
;rename the script for the guy and make a specific door to unlock or flag to set
;NO actual key is given to player, a global flag is set that removes the ownership on the beds.
;this script fires off when RENT is set true. Rent is set true throuhg the BEDS topic in dialogue, which all Publicans have.
;Each publican will also have a separate response to buying the bed, so they can give simple directions. There is also a default one.
short rent ;if room is rented, set through dialogue on this NPC
short rentDay ;the day of the rental
short rentMonth ;the month of the rental
short setup ;if setup has been done
short cleanup ;true if you want to cleanup all the flags, rental is over and can be reset
;this script also uses a global variable (Rent_Bed_Pelagiad). Make a new one for each rental. You can have as many
;beds as you want use that variable, it is used through the ownership data on the object reference
if ( rent == 1)
if ( setup == 0 )
set rentDay to Day
set rentMonth to Month
set setup to 1
set Rent_Meine_Taverne to 1 ;this is the flag for the ownership on the bed
"Rent_Meine_Taverne_Door"->unlock ;also needed if you have locked the room, use a specific objectRef
else ;setup is done so check to see if the day is over
if ( Day != rentDay )
set cleanup to 1
elseif ( Month != rentMonth )
set cleanup to 1
endif
endif
if ( CellChanged == 1 ) ;this is only needed if you've done a locked door. If so, you only want to do this on cell change so you don't lock them in the room
if ( cleanup == 1 ) ;this gets called when the rental is over and everything can be cleaned up
set rent to 0
set Rent_Meine_Taverne to 0
set setup to 0
set rentDay to 0
set rentMonth to 0
set cleanup to 0
"Rent_Meine_Taverne_Door"->lock 50
endif
endif
endif
end Pub_Meine_Taverne
...
Berechtigungen
Zitieren