Kleines Scriptproblem

[Satsuma]

Hi,
GetBUttonPressed geht nicht in einem OnActivate block. Dieser Weißheit hatte mich mal Low Post gelehrt. xD
Also müsstest du einen 2 Block einfügen, einen GameMode.

Code:

scn 000eisLockscript

short DoOnce
int Entscheidung 

begin onActivate
	if (DoOnce == 0)
                        Set DoOnce to 1
        endif
end

Begin GameMode
If (DoOnce == 1)
   	if (player.isSneaking == 1)
			MessageBox "Wie schwer soll die Tür verschlossen sein?", "Sehr schwer", "Schwer", "Mittel","Leicht","Sehr leicht"
			Set Entscheidung to GetButtonPressed
			if Entscheidung == 1
				lock 80
			elseif Entscheidung == 2
				lock 40
			elseif Entscheidung == 3
				lock 20
			elseif Entscheidung == 4
				lock 7
			else
				lock 99
			endif
		endif
	else
 		Activate
		Lock
	endif
       Set DoOnce to 0
end

[Low Post]

Eher nicht, da ist immer noch keine Absicherung für den Fall drin, dass GetButtonPressed nicht sofort den richtigen Wert annimmt.

Code:

scn 000eisLockscript

int Entscheidung 
int Menu

begin onActivate
	if player.isSneaking
		MessageBox "Wie schwer soll die Tür verschlossen sein?", "Sehr schwer", "Schwer", "Mittel","Leicht","Sehr leicht"
		Set Entscheidung to GetButtonPressed
		set Menu to 1
	else
		Activate
		Lock
	endif
end

Begin Gamemode
	if Menu
		if Entscheidung == -1
			set Entscheidung to GetButtonPressed
			Return
		elseif Entscheidung == 0
			lock 80
		elseif Entscheidung == 1
			lock 40
		elseif Entscheidung == 2
			lock 20
		elseif Entscheidung == 3
			lock 7
		else
			lock 99
		endif
		set Menu to 0
	endif
End

Außerdem hattest du ein Endif zu viel drin (heißt: Activate & Lock-Befehl wurden immer ausgeführt). Und du solltest dich daran gewöhnen, dass man eigentlich immer mit 0 zu Zählen beginnt (heißt: bei der erste Antwortmöglichkeit gibt GetButtonPressed 0 aus, bei der zweiten 1, etc.).

[eissceda]

Danke für die Hinweise. Dein Script funktioniert zwar immer noch nicht richtig, allerdings hat es mich auf eine Idee gebracht, wie ich das Script umschreiben kann, damit es funktioniert. Jetzt sieht es so aus. Und noch ein Hinweis für alle, die etwas Ähnliches machen wollen: Die Tür darf sich nicht ans Spielerlevel anpassen, da sonst das Spielerlevel auf die per Script zugewiesenen Werte addiert wird und das Script somit nicht mehr funktioniert. Es hat einige Zeit gedauert bis ich darauf gekommen bin, das das die Ursache für die falschen Locklevel mit der angepassten Variante sein könnte.

Code:

scn 000eisLockscript

short DoOnce
int Entscheidung 

begin onActivate
	if (player.isSneaking)
		if (DoOnce == 0)
			MessageBox "Wie schwer soll die Tür verschlossen sein?", "Sehr schwer", "Schwer", "Mittel","Leicht","Sehr leicht"
               Set DoOnce to 1
		endif
	else
 		Activate
		Lock
	endif
end

Begin GameMode
If (DoOnce)
       Set DoOnce to 0
			Set Entscheidung to GetButtonPressed
			if Entscheidung == 0
				lock 99
			elseif Entscheidung == 1
				lock 80
			elseif Entscheidung == 2
				lock 40
			elseif Entscheidung ==3
				lock 20
			elseif Entscheidung == 4
				lock 7
			else
				 Set DoOnce to 1
			endif
		endif
end

Edit: Ich glaube ich nehme doch die Variante von Low Post, da die etwas performanter sein dürfte.

[Low Post]

ó_0


Kommt so ziemlich aufs gleiche raus.
Was mann noch diesbezüglich machen könnte wäre das == 1 nach ja/nein-Abfragen zu löschen (weglassen bedeutet != 0). All zu groß sollte der Effekt aber auch nicht sein. Ich hab das trotzdem spaßeshalber mal gemacht.

[eissceda]

Es hat sich ergeben, das es doch nicht ganz funktioniert. Das Satsuma beim Zählen mit 1 angefangen hat liegt daran, das ich das auch gemacht habe. Und ich habe das gemacht, weil die 0 die Default-Variante, die verwendet wird, wenn keiner der anderen Werte passt. Ist mir eben bei ersten Tests im Spiel aufgefallen.