Unsichtbarer PC, Gegner ignorieren Beschwörungen

**Low Post** · 09.09.2008, 21:39

Was der ist von der selbst.

Dann ist's ja kein Wunder, dass die den nicht angreifen will.
Stimmt wohl was mit der Formel zu überprüfen der Feindlichkeit nicht.
Müsste wohl irgendwie überprüfen, ob es sich um eine beschworene Kreatur handelt. Weiß da jemand was?

**DWS** · 10.09.2008, 00:12

Wessen Formel?

Die Beschwörungen hat sie aus einem LAME Modul, u.a. hatte sie auch mal diese großen Klappergerüste beschworen. Wieso müsste sie auf die Idee kommen, ihre eigenen minions angreifen zu wollen? Ist das nicht hardcodiertes Verhalten?

**bg2408** · 10.09.2008, 04:55

Kurzer Zwischeneinwurf: Wie funktioniert die Speicherung von Debugnachrichten¿

**DWS** · 10.09.2008, 08:17

Auch zwischen fragt: Ich nehme an, die globale Variable für debug bleibt auf 1, wenn man danach einen Speicherpunkt setzt? Oder muss ich das im CS setzen?

**Low Post** · 10.09.2008, 17:49

Zitat von DWS

Wessen Formel?

Die Formel von der Wiki-Seite zu GetShouldAttack:

Code:

if ( callingActor.getAV aggression > 5 )
  if ( callingActor.getDisposition target < callingActor.getAV aggression )
    ; actor is hostile toward target
  endif
endif

Mir fällt gerade auf, da muss noch eine Überprüfung nach IsActorEvil (bzw. GetIsCreature) rein.

Zitat

Die Beschwörungen hat sie aus einem LAME Modul, u.a. hatte sie auch mal diese großen Klappergerüste beschworen. Wieso müsste sie auf die Idee kommen, ihre eigenen minions angreifen zu wollen? Ist das nicht hardcodiertes Verhalten?

Ich hab ihr gesagt, sie soll den angreifen anstelle des unsichtbaren aktuellen CombatTargets (dem Spieler, also dir), in dem ich ein StartCombat auf sie geworfen habe.
Das erst nachdem durch obige Formel herauskam, dass sie ihn ohne anderes CombatTarget angreifen würde. Warum mag die auch ihre eigenen beschworenen Viecher nicht. >_<

Zitat von bg2408

Kurzer Zwischeneinwurf: Wie funktioniert die Speicherung von Debugnachrichten¿

Mit Pluggy:

Code:

short EspID
long StringFileName

Begin OnReset
	set EspID to GetESP
	set StringFileName to CreateString EspID "Currently not Used" 1 1
	ESPToString StringFileName EspID
	set EspID to ( ( StringLen StringFileName ) - 4 )
	StringLen StringFileName EspID
	SetString -2000 "\DebugFile.txt" 1
	StringCat StringFileName -2000
	StringMsg StringFileName
End

Begin OnActivate
	SetString -2000 "DebugMessage" 1
	StringToTxtFile StringFileName -2000 1
End

Die Begin-Blöcke natürlich noch austauschen, aber die repräsentieren (vom Namen her) so ziemlich genau wofür die da sind.

Zitat von DWS

Auch zwischen fragt: Ich nehme an, die globale Variable für debug bleibt auf 1, wenn man danach einen Speicherpunkt setzt? Oder muss ich das im CS setzen?

Einfach per Konsole auf 1 (oder einen anderen Wert, ich überprüfe immer nur nach != 0

) setzen und speichern, das bleibt im SaveGame gespeichert.
Ich lösche immer nur alte Debug-Files, einfach weil die sonst zu groß werden würden und vorher ja anscheinend alles funktioniert hat.

**DWS** · 10.09.2008, 21:04

Zitat von Low Post

Ich hab ihr gesagt, sie soll den angreifen anstelle des unsichtbaren aktuellen CombatTargets (dem Spieler, also dir), in dem ich ein StartCombat auf sie geworfen habe.
Das erst nachdem durch obige Formel herauskam, dass sie ihn ohne anderes CombatTarget angreifen würde. Warum mag die auch ihre eigenen beschworenen Viecher nicht. >_<

That's gobbledygook (im Sinne von Fachchinesisch) to me.

**Low Post** · 10.09.2008, 23:23

Code:

if ( callingActor.getAV aggression > 5 )
  if ( callingActor.getDisposition target < callingActor.getAV aggression )
    ; actor is hostile toward target
  endif
endif

Diese Formel nutze ich zum überprüfen, ob Actor1 (CallingActor, eine Referenz mit einem unsichtbaren Angriffsziel) unter normalen umständen Actor2 (target, die neu ermittelte Referenz) angreifen würde.
Falls das zutrifft sage ich Actor1 mittels StartCombat, dass er/sie/es Actor2 angreifen soll.

Bei dem Log von dir war das der Fall (StartCombat wurde ausgelöst), allerdings hat sich das Angriffsziel nicht verändert.
Liegt anscheinend daran, dass der Skeleton Archer von ihr selbst beschworen wurde.
Seltsamerweise mag die den aber so wenig, dass sie ihn (laut obiger Formel) unter normalen Umständen angreifen würde.
Könnte allerdings auch an einer extrem hohen Aggression liegen, dann kann die den noch so lieben.

**DWS** · 12.09.2008, 22:09

Ein weiterer Invisible Freeze, diesmal in Villa Flugfels, 3 Sparring-Skelette kämpften gegen mich, ich machte mich irgendwann mal unsichtbar und dann passierte es. Könnte evtl. auch Zufall gewesen sein, das Spiel lief schon relativ lange.

**Low Post** · 14.09.2008, 13:50

Ich konnte den Bug leider nicht reproduzieren, daher ist das auch ein bisschen ein Schuss in's blaue: <klickst du hier>

Script sieht jetzt so aus (ich hab noch ein bisschen an der Formel zum überprüfen der Feindlichkeit geschraubt):

Code:

scn LPNISQuestScript

int ShutDown
short OBSEVersion
long Index
long Index2
float fQuestDelayTime
ref CombatTarget
ref Follower
ref OldReference
ref Reference

Begin Gamemode
	SetStage LPNISQuest 0
	if ( OBSEVersion >= 15 )
		if ( LPNISPluggyDebug )
			if ( IsPluginInstalled "OBSE_Elys_Pluggy" == 0 ) || ( GetPluginVersion "OBSE_Elys_Pluggy" < 112 )
				set LPNISPluggyDebug to 0
				MessageBox "Die DebugMessages dieses PIs benötigen Pluggy v112 (oder höher)."
				Return
			endif
			DestroyAllStrings
			set Index to GetEsp
			EspToString -2000 Index 1 1
			set Index to ( ( StringLen -2000 ) - 4 )
			StringLen -2000 Index 1
			SetString -2001 " - DebugFile.txt" 1
			StringCat -2000 -2001
			if ( GetGameRestarted )
				DelFile -2000
			endif
		endif
		set Index to 0
		SaveIP 1
		if ( Index < GetNumRefs 69 1 0 )
			set Reference to Apple
			if ( Index )
				set Reference to GetNextRef
			else
				set Reference to GetFirstRef 69 1 0
			endif
			if ( IsFormValid OldReference )
				set Index to ( Index + 1 )
				if ( Reference == OldReference )
					set OldReference to 0
					set Index to 0
				endif
				RestoreIP 1
			elseif ( Index == 0 ) && ( LPNISPluggyDebug )
				SetString -2001 "------------------------------------------------" 1
				StringToTxtFile -2000 -2001 1
			endif
			if ( LPNISPluggyDebug )
				FmtString -2001 1 "Reference: %n (%i), Index: %.0f", Reference, Reference, Index
				StringToTxtFile -2000 -2001 1
			endif
			if ( Reference.GetCombatTarget )
				set CombatTarget to Apple
				set CombatTarget to Reference.GetCombatTarget
				if ( LPNISPluggyDebug )
					FmtString -2001 1 "	CombatTarget: %n (%i)", CombatTarget, CombatTarget
					StringToTxtFile -2000 -2001 1
				endif
				if ( CombatTarget.HasMagicEffect INVI ) && ( Reference.GetActorValue Aggression >= 5 )
					if ( LPNISPluggyDebug )
						FmtString -2001 1 "		HasMagicEffect INVI"
						StringToTxtFile -2000 -2001 1
					endif
					set OldReference to Apple
					set OldReference to Reference
					if ( LPNISPluggyDebug )
						FmtString -2001 1 "		OldReference: %n (%i)", OldReference, OldReference
						StringToTxtFile -2000 -2001 1
					endif
					set Index2 to 0
					SaveIP 2
					if ( Index2 < GetNumRefs 69 1 0 )
						set CombatTarget to Apple
						if ( Index2 )
							set CombatTarget to GetNextRef
						else
							set CombatTarget to GetFirstRef 69 1 0
						endif
						if ( CombatTarget.HasMagicEffect INVI == 0 ) && ( Reference.GetIsReference CombatTarget == 0 )
							if ( ( ( Reference.GetDisposition CombatTarget < Reference.GetActorValue Aggression ) || ( Reference.IsActorEvil != CombatTarget.IsActorEvil ) ) && ( Reference.GetActorValue Aggression > 5 ) ) || ( CombatTarget.GetCombatTarget == Reference )
								if ( LPNISPluggyDebug )
									FmtString -2001 1 "			NewCombatTarget: %n (%i)", CombatTarget, CombatTarget
									StringToTxtFile -2000 -2001 1
								endif
								set Index to 0
								SaveIP 3
								if ( Index < Reference.GetNumFollowers )
									set Follower to Apple
									set Follower to Reference.GetNthFollower Index
									if ( CombatTarget.GetIsReference Follower )
										if ( LPNISPluggyDebug )
											FmtString -2001 1 "			%n (%i) is a Follower of %n (%i)", CombatTarget, CombatTarget, Reference, Reference
											StringToTxtFile -2000 -2001 1
										endif
										set Index2 to ( Index2 + 1 )
										RestoreIP 2
									else
										set Index to ( Index + 1 )
										RestoreIP 3
									endif
								endif
								set Index to 0
								SaveIP 4
								if ( Index < CombatTarget.GetNumFollowers )
									set Follower to Apple
									set Follower to CombatTarget.GetNthFollower Index
									if ( Reference.GetIsReference Follower )
										if ( LPNISPluggyDebug )
											FmtString -2001 1 "			%n (%i) is a Follower of %n (%i)", Reference, Reference, CombatTarget, CombatTarget
											StringToTxtFile -2000 -2001 1
										endif
										set Index2 to ( Index2 + 1 )
										RestoreIP 2
									else
										set Index to ( Index + 1 )
										RestoreIP 3
									endif
								else
									Reference.StartCombat CombatTarget
									if ( LPNISPluggyDebug )
										FmtString -2001 1 "			%n (%i).StartCombat %n (%i)", Reference, Reference, CombatTarget, CombatTarget
										StringToTxtFile -2000 -2001 1
									endif
								endif
							else
								set Index2 to ( Index2 + 1 )
								RestoreIP 2
							endif
						else
							set Index2 to ( Index2 + 1 )
							RestoreIP 2
						endif
					elseif ( Player.HasMagicEffect INVI == 0 )
						if ( ( Reference.GetDisposition Player < Reference.GetActorValue Aggression ) && ( Reference.GetActorValue Aggression > 5 ) ) || ( CombatTarget.GetCombatTarget == Reference )
							if ( LPNISPluggyDebug )
								FmtString -2001 1 "			%n (%i).StartCombat Player", Reference, Reference
								StringToTxtFile -2000 -2001 1
							endif
							Reference.StartCombat Player
						endif
					endif
					Return
				endif
			endif
			set Index to ( Index + 1 )
			RestoreIP 1
		endif
	elseif ( Shutdown == 2 )
		if ( OBSEVersion >= 11 )
			con_Quitgame
		else
			Player.Disable
		endif
	elseif ( Shutdown == 1 )
		set Shutdown to ( GetButtonPressed + 2 )
	elseif ( OBSEVersion )
		set Shutdown to ( GetButtonPressed + 2 )
		MessageBox "Dieses PI benötigt OBSE v0015 oder höher. Du verwendest momentan OBSE v%04.0f", OBSEVersion
	else
		set Shutdown to ( GetButtonPressed + 2 )
		MessageBox "Dieses PI benötigt OBSE v0015 oder höher. Stelle sicher, dass du Oblivion über die 'obse_loader.exe' startest."
	endif
End

PS:
Ab jetzt wird Pluggy v112 oder höher für die Debugnachrichten benötigt.

**DWS** · 13.11.2008, 10:14

Ab jetzt (mit T.I.E.) scheint ein neues Problem aufzutauchen. Die NPC Beschwörer beschwören meistens mehrere summons gleichzeitig. Mal bekämpfen sich diese 2-3 summons gegenseitig, mal gehen sie sogar auf ihren Beschwörer los oder umgekehrt, es ist in dem Durcheinander kaum noch zu sehen, wer wen angreift.

Wenn ich dieses script deaktiviere, ist anscheinend Ruhe im (gleichen) gegnerischen Rudel.

**Low Post** · 13.11.2008, 16:01

Das liegt leider daran, dass GetNthFollower/GetNumFollowers keine Beschwörungen berücksichtigt und es auch sonst keine Möglichkeit gibt das zu überprüfen.
Heißt: da kann ich leider nichts machen.

Sollte doch jemand einen Weg kennen das zu beheben so möge er/sie es mir doch bitte mitteilen.

**DWS** · 10.12.2008, 13:20

T.I.E. benutze ich gerade nicht mehr, aber vielleicht kommen in FCOM auch irgendwann Beschwörer mit multiple summons vor(?)...

Könntest du es auch auf eine nur auf die Arena, oder vielleicht auf Interieur begrenzte Version umschreiben?

Ich glaube, in freier Wildbahn macht das doch noch zu viele Probleme. Besonders bei "Außenquests" ist es oft so, dass die zu erledigenden Gegner über die halbe Karte weglaufen und man sie nicht mehr wieder findet (z.B. Anvil MG Recommendation Quest; damit habe ich getestet mit und ohne diese Mod). Bei einem Gegner geht es vielleicht gerade noch, aber wenn 2 oder 3 questrelevante NPCs in alle möglichen Richtungen kilometerweit hinter dem nächsten Reh herlaufen, verliert man sie immer wieder.

**bjoernret** · 20.05.2009, 20:49

Danke für die tolle Mod

**NewRaven** · 21.05.2009, 02:44

Hey, Lowi, irgendwie erkennt die Version meine OBSE 0017 Beta 2 Version nicht. Ich bekomme beim Start eine Endlosschleife mit dem Hinweis, das dieses PlugIn OBSE 0017 Beta 2 braucht, ich Version 0017 installiert hätte. Diese Endlosschleife der Messagebox resultiert dann auch in nem Crash. Ich hab übrigens ganz sicher Beta 2 installiert, weil ich noch nen anderen Mod nutze, der zwingend diese Version braucht (und funktioniert

) und weil ich zusätzlich dazu auch noch in der Lage bin zu lesen. Ist auch kein Pre-Release der Beta oder sonstiges - zumindest wüßte ich nicht, wie das gehen sollte

**Low Post** · 21.05.2009, 12:22

Ja ja, mea culpa.
Was ändern die auch plötzlich die Revision-Nummer für Beta 2.

Mal ganz abgesehen, dass die auch ohne Änderung nicht erkannt worden wäre.

Endlosschleife sollte auch beseitigt sein und gleich nach der Meldung zum Absturz führen.

Link bleibt der gleiche wie vorhin.

**Low Post** · 26.04.2010, 18:37

Mit der neuen OBSE-Versionen kamen die Funktionen GetAllies & GetTargets, wodurch die Gegner- & Verbündeten-Suche komplett von meiner Seite an OBSE abgegeben würde. Einbauen würde vermutlich nicht länger als eine Stunde dauern, aber bevor ich mir die Mühe macht, hat überhaupt jemand Interesse an einem solchen Update?

**DWS** · 01.05.2010, 12:56

Ich benutze seit einiger Zeit Combat Hide und nach ein paar Sekunden Suche wenden sich die Gegner damit dem nächstmöglichen Gegner zu. Ich müsste es noch mal etwas genauer beobachten, aber eigentlich scheint mich an dem Verhalten damit nichts mehr so gewaltig zu stören.

Thema: Unsichtbarer PC, Gegner ignorieren Beschwörungen

Themen-Optionen

Anzeige

Hybrid-Darstellung

Berechtigungen