Azuras Stern

**Katan** · 30.01.2008, 22:16

Das obere Script funktioniert nicht so dolle. Das, was ich jetzt poste, funktioniert dagegen wunderbar (soweit ich es getestet habe).

Code:

ScriptName EnchantingStationScript

;Script for activation of Enchanting Station (which brings up Enchant Menu)

short HasSoulGem

Begin OnActivate

	if isActionRef player == 1
		showEnchantment
	endif

	if ( player.GetItemCount "DeinSeelenstein" >= 1 ) && ( HasSoulGem == 0 )
		set HasSoulGem to 1
	endif

End

Begin GameMode

	if ( HasSoulGem == 1 ) && ( player.GetItemCount "DeinSeelenstein" >= 1 )
		set HasSoulGem to 0
		return
	endif

	if ( HasSoulGem == 1 ) && ( player.GetItemCount "DeinSeelenstein" <= 0 )
		message " "
		message " "
		player.AddItem "DeinSeelenstein" 1
		set HasSoulGem to 0
	endif

End

Die Zeilen

message " "
message " "

dienen der Verhinderung von so bezeichnetem Message Spam (Die Nachricht "DeinSeelenstein added" wird nicht kommen, stattdessen nur eben das Oblivion-Zeichen; wenn du willst, dass diese Nachricht angezeigt wird, musst du nur die beiden Zeilen aus dem Script löschen). So erhält der Spieler immer direkt nach Nutzung des Altars einen neuen Seelenstein derselben ID, wenn er den alten dann nicht mehr im Inventar hat - den er in dem Fall ja nur durch Nutzung des Altars verloren haben kann.

Das Recharge-Script dagegen ist eine andere Sache (danke @ Grimoa für die Aufklärung). Befindet sich der Spieler im selben Raum mit einem Objekt, auf dem ein Script mit GameMode-Block liegt - wie in diesem Fall der Verzauberungsaltar -, so wird der GameMode-Block des Scripts einmal pro Frame durchgearbeitet. Das ist bei Recharge nicht möglich; GameMode wird innerhalb von Menüs ignoriert. Um ehrlich zu sein, ich habe keine Ahnung wie genau das mit dem Recharge-Menü funktioniert, aber über ein Script offensichtlich nicht.

**Nord** · 31.01.2008, 14:56

Ähhh... ich versteh grade nicht wirklich viel, sorry, aber ist das Skript über welches ihr jetzt grad gesprochen habt dafür da, damit ich meinen selbstgebauten Stern am Verzauberungsaltar entleeren kann und trotzdem behalte??? Das wäre ja schonmal nicht schlecht!

Aber die Sache mit dem Waffe aufladen und Stern behalten scheint mir fast nicht lösbar... ich habe zwar nicht wirklich Ahnung, aber wenn es einfach wäre, warum hätten die Entwickler es dann nicht einfach auch mit Skript machen sollen, statt es in der .exe zu codieren???

Und nochmal vielen Dank für eure Mühen!

**Katan** · 31.01.2008, 17:25

Das Script in meinem Post #18 ist für die Verzauberungsaltar-Sache. Scripts heißen immer so, wie die erste Zeile - ScriptName, wahlweise auch kurz scn - es vorschreibt. Das Script, das du ersetzen musst, heißt also EnchantingStationScript. Einfach meines drüber kopieren und dann abspeichern.

Das mit dem Recharge-Script dürfte ziemlich unmöglich sein, yeah, bedenke aber, dass ich auch kein Scripting-Profi bin. OBSE (Oblivion Script Extender) bringt immer neue Scripting-Möglichkeiten ins Spiel, vielleicht kommt irgendwann auch noch was Hilfreiches, das man hier anwenden kann.

**Grimoa** · 31.01.2008, 18:21

Aber müsste man nicht mit "equip" feststellen können, wann der SPieler den Seelenstein im Inventar anklickt? Also in dem Moment, wo er ihn anklickt, gucke ich nach, wieviele Seelensteine im Inventar vorhanden sind, und wenn das Inventar geschlossen wird (GameMode) gucke ich wieder nach, und fülle bei Bedarf auf. Noch ein paar Variablen, damit das Auffüllen nur einmal geschieht und das Skript an den Seelenstein gehängt.
Natürlich unter der Annahme, dass das Aufladen-menu dann trotzdem erscheint, ohne dass ich es expliziet aufrufe. Das soll einfach erscheinen, weil der geskriptete Gegenstand ein Seelenstein ist.

Ist nur sone wirre Theorie von mir.

**Katan** · 31.01.2008, 20:01

@ Grimoa
Zwei Schlaue, fast ein Gedanke. Etwas Ähnliches ist mir vorhin auch eingefallen und ich habe es gleich mal ausprobiert. Es funktioniert; wie immer kann ich das nur im Bereich meiner Testereien garantieren. Existierende Scripte müssen dabei nicht modifiziert werden.

Was man braucht: Zwei neue Scripte, zwei neue Quests. Da die Scripte nicht besonders groß sind, entstehen keine besonderen Performanceeinbußen. Beide müssen natürlich Quest-Scripte sein.

Code:

scn SoulGemReAddScript01

short controlvar

Begin MenuMode 1049
;Recharge-Menü

	if ( player.getitemcount "Seelenstein" >= 1 ) && ( controlvar == 0 )
		set controlvar to 1
	endif

End

Begin GameMode

	if ( controlvar == 1 ) && ( player.getitemcount "Seelenstein" >= 1 )
		set controlvar to 0
	endif

	if ( controlvar == 1 ) && ( player.getitemcount "Seelenstein" <= 0 )
		message " "
		message " "
		player.additem "Seelenstein" 1
		set controlvar to 0
	endif

End

Code:

scn SoulGemReAddScript02

short controlvar

Begin MenuMode 1042
;Enchantment-Menü

	if ( player.getitemcount "Seelenstein" >= 1 ) && ( controlvar == 0 )
		set controlvar to 1
	endif

End

Begin GameMode

	if ( controlvar == 1 ) && ( player.getitemcount "Seelenstein" >= 1 )
		set controlvar to 0
	endif

	if ( controlvar == 1 ) && ( player.getitemcount "Seelenstein" <= 0 )
		message " "
		message " "
		player.additem "Seelenstein" 1
		set controlvar to 0
	endif

End

Du erstellst zwei neue Quests und hängst an jedes eines der Scripte (Start Game Enabled muss markiert sein). OnEquip könnte wohl auch irgendwie funktionieren, kann Grimoa ja ausprobieren. Ich tu's jedenfalls nicht.

**Low Post** · 31.01.2008, 21:55

Man könnte auch alles in eine Quest packen. Außerdem deckt Katans Skript nicht die Möglichkeit von mehreren Seelensteinen im Inventar ab.

Code:

scn AzurasStar2QuestScript

short x
short SoulGemMenu

Begin Menumode
 if ( ( Menumode 1042 ) || ( Menumode 1049 ) )          ;Enchantment & Recharge Menu
  if ( SoulGemMenu == 0 )
   set x to Player.GetItemCount [ID deines Seelensteins]
   set SoulGemMenu to 1
  endif
 else
  if ( x != Player.GetItemCount [ID deines Seelensteins] )
   if ( SoulGemMenu )
    set x to ( x - Player.GetItemCount [ID deines Seelensteins] )
;    Message " "
;    Message " "
;zum ausblenden der Nachricht einfach die beiden obigen Zeilen entkommentieren (Achtung: blendet evtl. auch wichtige Nachrichten aus)
    if ( x > 0 )
     Player.AddItem [ID deines Seelensteins] x
    else
     MessageBox "Während dem Verzaubern/Waffe aufladen wurde ein [Name deines Seelensteins] hinzugefügt."
    endif
   endif
   set x to Player.GetItemCount [ID deines Seelensteins]
   set SoulGemMenu to 0
  endif
 endif
End

Begin Gamemode
 if ( x != Player.GetItemCount [ID deines Seelensteins] )
  if ( SoulGemMenu )
   set x to ( x - Player.GetItemCount [ID deines Seelensteins] )
;   Message " "
;   Message " "
;zum ausblenden der Nachricht einfach die beiden obigen Zeilen entkommentieren (Achtung: blendet evtl. auch wichtige Nachrichten aus)
   if ( x > 0 )
    Player.AddItem [ID deines Seelensteins] x
   else
    MessageBox "Während dem Verzaubern/Waffe aufladen wurde ein [Name deines Seelensteins] hinzugefügt."
   endif
  endif
 set x to Player.GetItemCount [ID deines Seelensteins]
 set SoulGemMenu to 0
 endif
End

Skript ist, wie das von Katan, einfach nur heruntergeschrieben und ungetestet.
Müsste aber eigentlich funktionieren.

Solltest du dich entschließen auch noch OBSE zu verwenden kann man damit auch noch folgende Befehle verwenden:
GetCreatureSoulLevel
GetCurrentSoulLevel
GetSoulGemCapacity
GetSoulLevel
IsSoulGem
SetCurrentSoulLevel
SetSoulGemCapacity
SetSoulLevel

**Grimoa** · 31.01.2008, 23:44

Zitat von Katan

OnEquip könnte wohl auch irgendwie funktionieren, kann Grimoa ja ausprobieren. Ich tu's jedenfalls nicht.

Jaaaa..... vielleicht... aber vermutlich nicht so bald. Wenn ich das nächste mal Zeit habe, das CS auszupacken, bau ich mir erstmal ne Oblivionebene.

Ich wusste bei meinem Vorschlag nicht, dass es sowas

Code:

Begin MenuMode 1049 ;Recharge-Menü

gibt. Das ist natürlich viel direkter.

Mir ist aber glaube ich ein "Fehler" aufgefallen, der von schummelnden Spielern ausgenutzt werden könnte.(Würde bei meiner Idee genauso auftreten.)
Nachdem das Zauber bzw Aufladen-Menu aufgerufen wurde, wird ja abgefragt, wieviele Seelensteine der Spieler hat. Wenn man jetzt das Aufladen-Menu abbricht, ist man ja erstmal nur wieder im Inventar. Jetzt schmeißt man einen Seelenstein weg und schließt das Inventar. Damit ist man jetzt im GameMode, und es wird überprüft, ob ein Stein weniger da ist. Und ja, tatsächlich, ein Stein fehlt. Er wird also ersetzt. Danach kann man den Stein, den man grade weggelegt hat, aufheben. Und so weiter. Eine unerschöpfliche Seelensteinquelle.
Jedenfalls, wenn ich das richtig durchdacht habe.

Außerdem gehen deine Skripte jetzt davon aus, dass der neue Seelenstein auch nur einmal vorhanden ist, nicht mehrmals, richtig? Sonst müsste man noch präzise abfragen, wieviele Steine und dann die Differenz hinzufügen. Aber das sind ja Details.
Oha, da hat LowPost dazwischengescriptet

Auf jeden Fall saubere Arbeit, Katan!

**Katan** · 01.02.2008, 03:04

@ Low Post
Kann es sein, dass du zwei Mal vergessen hast, den Wert einer Variable abzufragen? Du hast zwei Mal "if ( SoulGemMenu )" drin. Es ist darüber hinaus aber unnötig, den Verbrauch mehrerer Seelensteine in einem Durchgang zu berücksichtigen. Man kann weder bei der Verzauberung noch beim Recharge mehr als einen auf einmal benutzen. Will man einen weiteren Gegenstand verzaubern/aufladen, muss man abermals das Menü öffnen. Oder du hast das nun so gemeint, dass man bei Recharge nicht zwangsweise aus dem MenuMode raus geht und mehrere nacheinander benutzt... was aber auch nichts bringt, weil die Variable x die vorhandene Menge an Seelensteinen bei jeder Benutzung mit dem neuen überschreibt.

@ Grimoa
Eigentlich hatte ich mir fest vorgenommen, dir zu widersprechen, aber... crap - du hast Recht. Ich habe eine weitere Variable eingebaut, um das zu unterbinden, aber das Posten dieses Scripts erübrigt sich, weil es nicht funktionieren kann. Jedenfalls nicht auf gewünschte Weise.

Ich habe eine weitere Variable (cheater) eingebaut, die die durch count gespeicherte Ursprungsmenge mit der vorhandenen abgleicht, sobald cheater auf 1 steht und der Spieler im Inventar (MenuMode 1002) ist. Entspricht die Ursprungsmenge der vorhandenen Menge, werden die Variablen allesamt auf 0 zurückgesetzt und der Spieler erhält im GameMode keinen Seelenstein, da kann er schmeißen wie er will. Haken an der Sache: Spieler geht ins Recharge-Menü (controlvar to 1, count to getitemcount, cheater to 1), läd eine Waffe auf, kommt zurück ins Inventar (count != vorhandene Seelensteinmenge, kein Zurücksetzen der Variablen) - verlässt der Spieler das Inventar und geht in GameMode, erhält er den Seelenstein. Geht er aber NICHT in GameMode, sondern klickt noch mal auf einen Seelenstein, gibt's ein Problem; das fängt mit count an, die die JETZT vorhandene Menge speichert, und endet damit, dass der Spieler, wenn er auf Abbrechen klickt, den Seelenstein aus dem vorhergehenden Aufladen nicht bekommt; würde der Spieler dagegen nicht abbrechen und abermals aufladen, danach ins Inventar kommen und dann in GameMode, würde er nur den einen Seelenstein aus der zweiten Benutzung zurückerhalten, nicht aber aus der ersten.

**Low Post** · 01.02.2008, 06:53

Hauptproblem bei deinem Skript ist vor allem, dass du bei GetItemCount <= 0 abfragst.
Was passiert aber, wenn der Spieler am Anfang 2 Seelensteine hatte?
Dann hat er nach dem aufladen 1, dein Skript meint, er hat keinen verbraucht und fügt auch keinen neuen hinzu. Das ist eigentlich der Hauptgrund für die x-Variable. Bei dem AddItem hab ich mich nur etwas gespielt. Außerdem war ich mir nichtmehr sicher, ob man evtl. doch mehrere verwenden kann.
Da das Skript aber so "nur" alle 5 Sekunden läuft und geübte Spieler da mehr als einen Seelenstein verbraten können ist das ganze gar nicht mal so sinnlos.

Bezüglich abfrage vergessen:
da GetSoulGemMenu nur 0 oder 1 werden kann reicht das zum überprüfen von 1 durchaus aus. Beim einzigen mal wo's 0 sein muss hab ich es aber vergessen, stimmt schon.

**Katan** · 01.02.2008, 13:00

Yeah, das ist mir auch gerade aufgefallen. Ich sollte es mir in Zukunft sparen, so früh morgens irgendwelche Schlussfolgerungen aufstellen zu wollen. Sorry. Das Problem mit der mehrmaligen Nutzung aber bleibt. Vielleicht fällt dir dazu ja noch irgendwas ein.

**Nord** · 01.02.2008, 15:08

Hilfe!!! Ich finde es ja schön, dass sich hier um das Thema so eine lebhafte Diskussion entwickelt, aber ich kann leider kaum folgen... seid mir also nicht böse, wenn ich manchmal auf der Leitung stehe... Jedenfalls soweit ich es mitbekommen habe, habt ihr ja das Problem des Verschwindens bei Altarnutzung schon gelöst (die Feststellung hatte ich ja schonmal gepostet, will nur sichergehen, dass ich da jetzt nicht irgendwas übersehen habe...).

Ach ja mir ist was zu deiner Frage eingefallen, Katan. "GameMode" ist das Spiel selber, also die Spielwelt, in der man sich bewegt? (Hab ich so verstanden...!?) Die Lösung mag manchem jetzt vielleicht unprofessionell vorkommen, aber da wir ja nicht wie Bethesda an die .exe kommen, muss es ja auch nicht so perfekt sein. Worauf ich raus will: Wie wäre es, wenn man einen Befehl dazuschreibt, dass nach Schliessen des Aufladen- Menüs (Recharge-Menü?) das Inventar des Spielers automatisch auch geschlossen wird??? Dann wäre er wieder in GameMode und müsste das Inventar zur eneuten Aufladung auch neu öffnen (ok ein Tastendruck mehr

)... und dann darf das Skript ja auch wieder mit Zählen anfangen, oder?

Edit1: So hab gerade das Skript für den Altar ersetzt (nochmal Dank an alle für diese Mühen!), beim Speichern kam aber eine Fehlermeldung: Item "DeinSeelenstein" not found for parameter Objekt ID. Compiled Script not saved!. Da hab ich mir gedacht, dass das "DeinSeelenstein" nur ein Platzhalter war und hab die Editor ID von meiner Kopie eingegeben (AzurasSun). Jetzt hat's gespeichert. War das richtig oder falsch???

Edit2:

Zitat von Katan

Das, was ich jetzt poste, funktioniert dagegen wunderbar (soweit ich es getestet habe).

Joa Edit1 hat sich erledigt, ich hab es grad auch einfach mal getestet und es läuft auch bei mir wunderbar (warum auch nicht). DAS IST SUPER! Echt meinen grössten Respekt an alle, die sowas schreiben können! Nächstes Zwischenziel: Das Auflade- Menü!

**Low Post** · 01.02.2008, 21:58

Zitat von Katan

Yeah, das ist mir auch gerade aufgefallen. Ich sollte es mir in Zukunft sparen, so früh morgens irgendwelche Schlussfolgerungen aufstellen zu wollen. Sorry. Das Problem mit der mehrmaligen Nutzung aber bleibt. Vielleicht fällt dir dazu ja noch irgendwas ein.

Naja, bei meinem Skript wird ja die Anzahl der entfernten Gegenstände wieder hinzugefügt. Wenn man das noch genauer haben will kann man natürlich noch etwas mit fQuestDelayTime herumexperimentieren, was ich aber nur ungern tun würde.

Zitat von JaMak062

[...]
Ach ja mir ist was zu deiner Frage eingefallen, Katan. "GameMode" ist das Spiel selber, also die Spielwelt, in der man sich bewegt? (Hab ich so verstanden...!?) Die Lösung mag manchem jetzt vielleicht unprofessionell vorkommen, aber da wir ja nicht wie Bethesda an die .exe kommen, muss es ja auch nicht so perfekt sein. Worauf ich raus will: Wie wäre es, wenn man einen Befehl dazuschreibt, dass nach Schliessen des Aufladen- Menüs (Recharge-Menü?) das Inventar des Spielers automatisch auch geschlossen wird??? Dann wäre er wieder in GameMode und müsste das Inventar zur eneuten Aufladung auch neu öffnen (ok ein Tastendruck mehr

)... und dann darf das Skript ja auch wieder mit Zählen anfangen, oder?

Bin zwar nicht Katan, aber ich antworte darauf trotzdem mal.
Man kann einfach allgemein auch im Menumode abfragen, damit wäre das kein Problem.

[QUOTE=JaMak062;1989811]Edit1: So hab gerade das Skript für den Altar ersetzt (nochmal Dank an alle für diese Mühen!), beim Speichern kam aber eine Fehlermeldung: Item "DeinSeelenstein" not found for parameter Objekt ID. Compiled Script not saved!. Da hab ich mir gedacht, dass das "DeinSeelenstein" nur ein Platzhalter war und hab die Editor ID von meiner Kopie eingegeben (AzurasSun). Jetzt hat's gespeichert. War das richtig oder falsch???[/Quopte]

Ist schon richtig, Sachen die irgentwie speziell gekennzeichnet wurden ( bei mir mit eckigen Klammer, bei Katan mit Anführungszeichen ) sind meistens Platzhalter, die man mit der entsprechenden ID ersetzen muss.

Zitat von JaMak062

Edit2:

Joa Edit1 hat sich erledigt, ich hab es grad auch einfach mal getestet und es läuft auch bei mir wunderbar (warum auch nicht). DAS IST SUPER! Echt meinen grössten Respekt an alle, die sowas schreiben können! Nächstes Zwischenziel: Das Auflade- Menü!

Welches Skript verwendest du denn?
Bei den Questskripts (letzten von Katan, bzw. mein Skript) ist das aufladen jeweils integriert. Außerdem gibt dass dann auch keine Konflikte mit anderen PIs, die auch den Verzauberungsaltar verändern, bzw. neue Möglichkeiten zum Verzaubern/Aufladen einfügen.

Zum verwenden einfach eine Quest erstellen, den Hacken bei SetGameStarted lassen/hintun, und das jeweilige Skript unter Questdata zuweisen.

**Nord** · 02.02.2008, 11:03

Moinmoin.

Ich verwende das erweiterte Altar- Skript aus Katan's Post #18, weil das das Einzige war, das bisher voll funktionsfähig schien. Bei den anderen Skripts hat immer irgendwer einen Einwand gehabt... und Katans hat in seinem letzten Post ja auch noch behauptet, dass es ein Problem gäbe?! Da dort nichts gegenteiliges kam, bin ich davon ausgegangen, dass es stimmt. Dass du jetzt sagst, dass du das Problem eigentlich schon gelöst hast, ist natürlich super, aber das wusste ich ja nicht und aus dem Skript konnte ich es auch nicht ersehen.

Na gut, dann erklärt mir doch bitte mal einer genau, wie ich dein Skript, Low Post, da einbinden kann und dann versuch ich das! Wie erstellt man eine Quest? Und wo ist Questdata? Und muss ich jetzt auf Azuras Sonne ein Quest legen oder muss ich nur dem Questskript Azuras Sonne zuweisen? Und wie soll die Quest überhaupt ablaufen??? Ok sorry, sind verdammt viele Fragen...

Thema: Azuras Stern

Themen-Optionen

Anzeige

Hybrid-Darstellung

Berechtigungen